Add 'nodejs-node-pre-gyp/' from commit 'd94eefc1a14868ede3d11e2a83541a235e2c8184'

git-subtree-dir: nodejs-node-pre-gyp
git-subtree-mainline: 7b6a940fd5
git-subtree-split: d94eefc1a1

nodejs-node-pre-gyp/.SRCINFO

@@ -0,0 +1,16 @@
+pkgbase = nodejs-node-pre-gyp
+	pkgdesc = Node.js tool for easy binary deployment of C++ addons
+	pkgver = 0.17.0
+	pkgrel = 2
+	url = https://github.com/mapbox/node-pre-gyp
+	arch = any
+	license = BSD
+	makedepends = npm
+	makedepends = jq
+	depends = nodejs
+	noextract = node-pre-gyp-0.17.0.tgz
+	source = https://registry.npmjs.org/node-pre-gyp/-/node-pre-gyp-0.17.0.tgz
+	sha1sums = 5af3f7b4c3848b5ed00edc3d298ff836daae5f1d
+
+pkgname = nodejs-node-pre-gyp
+

nodejs-node-pre-gyp/.gitignore

@@ -0,0 +1,4 @@
+*
+!.gitignore
+!PKGBUILD
+!.SRCINFO

nodejs-node-pre-gyp/PKGBUILD

@@ -0,0 +1,35 @@
+# Maintainer: Bert Peters <bert@bertptrs.nl>
+_npmname=node-pre-gyp
+pkgname=nodejs-node-pre-gyp
+pkgver=0.17.0
+pkgrel=2
+pkgdesc="Node.js tool for easy binary deployment of C++ addons "
+arch=('any')
+url="https://github.com/mapbox/node-pre-gyp"
+license=('BSD')
+depends=('nodejs')
+makedepends=('npm' 'jq')
+source=("https://registry.npmjs.org/$_npmname/-/$_npmname-$pkgver.tgz")
+noextract=("$_npmname-$pkgver.tgz")
+sha1sums=('5af3f7b4c3848b5ed00edc3d298ff836daae5f1d')
+
+package() {
+	npm install -g --prefix "$pkgdir/usr" "$_npmname-$pkgver.tgz"
+
+	# Remove references to $pkgdir
+	find "$pkgdir" -type f -name package.json -print0 | xargs -0 sed -i "/_where/d"
+
+	# Remove references to $srcdir
+	local tmppackage="$(mktemp)"
+	local pkgjson="$pkgdir/usr/lib/node_modules/$_npmname/package.json"
+	jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
+	mv "$tmppackage" "$pkgjson"
+	chmod 644 "$pkgjson"
+
+	# Fix a weird permission thing
+	chmod 755 "$pkgdir/usr/lib/node_modules"
+
+	# Install LICENSE in a more findable spot.
+	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
+		"$pkgdir/usr/lib/node_modules/$_npmname/LICENSE"
+}