upgpkg: nodejs-node-pre-gyp 1.0.6-1

upstream release

upgpkg: nodejs-node-pre-gyp 1.0.6-1

Upstream changed package names on npm. This required some changes. For
more details, see [1].

[1]: https://github.com/mapbox/node-pre-gyp#special-note-on-previous-package

nodejs-node-pre-gyp/.SRCINFO

@@ -0,0 +1,15 @@
+pkgbase = nodejs-node-pre-gyp
+	pkgdesc = Node.js tool for easy binary deployment of C++ addons
+	pkgver = 1.0.6
+	pkgrel = 1
+	url = https://github.com/mapbox/node-pre-gyp
+	arch = any
+	license = BSD
+	makedepends = npm
+	makedepends = jq
+	depends = nodejs
+	noextract = node-pre-gyp-1.0.6.tgz
+	source = https://registry.npmjs.org/@mapbox/node-pre-gyp/-/node-pre-gyp-1.0.6.tgz
+	sha1sums = f859d601a210537e27530f363028cde56e0cf962
+
+pkgname = nodejs-node-pre-gyp

nodejs-node-pre-gyp/.gitignore

@@ -0,0 +1,4 @@
+*
+!.gitignore
+!PKGBUILD
+!.SRCINFO

nodejs-node-pre-gyp/PKGBUILD

@@ -0,0 +1,35 @@
+# Maintainer: Bert Peters <bert@bertptrs.nl>
+_npmname=node-pre-gyp
+pkgname=nodejs-node-pre-gyp
+pkgver=1.0.6
+pkgrel=1
+pkgdesc="Node.js tool for easy binary deployment of C++ addons "
+arch=('any')
+url="https://github.com/mapbox/node-pre-gyp"
+license=('BSD')
+depends=('nodejs')
+makedepends=('npm' 'jq')
+source=("https://registry.npmjs.org/@mapbox/$_npmname/-/$_npmname-$pkgver.tgz")
+noextract=("$_npmname-$pkgver.tgz")
+sha1sums=('f859d601a210537e27530f363028cde56e0cf962')
+
+package() {
+	npm install -g --prefix "$pkgdir/usr" "$_npmname-$pkgver.tgz"
+
+	# Remove references to $pkgdir
+	find "$pkgdir" -type f -name package.json -print0 | xargs -0 sed -i "/_where/d"
+
+	# Remove references to $srcdir
+	local tmppackage="$(mktemp)"
+	local pkgjson="$pkgdir/usr/lib/node_modules/@mapbox/$_npmname/package.json"
+	jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
+	mv "$tmppackage" "$pkgjson"
+	chmod 644 "$pkgjson"
+
+	# Fix a weird permission thing
+	chmod 755 "$pkgdir/usr/lib/node_modules"
+
+	# Install LICENSE in a more findable spot.
+	install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
+		"$pkgdir/usr/lib/node_modules/@mapbox/$_npmname/LICENSE"
+}